5.2 Assignment Statements

danger

This Reference Manual output has not been verified, and may contain omissions or errors. Report any problems on the tracking issue

1

[An assignment_statement replaces the current value of a variable with the result of evaluating an expression.]

Syntax

2

assignment_statement ::= 
   variable_name := expression;

3

The execution of an assignment_statement includes the evaluation of the expression and the assignment of the value of the expression into the target. [An assignment operation (as opposed to an assignment_statement) is performed in other contexts as well, including object initialization and by-copy parameter passing.] The target of an assignment operation is the view of the object to which a value is being assigned; the target of an assignment_statement is the variable denoted by the variable_name.

3.a

discussion

Don't confuse this notion of the “target” of an assignment with the notion of the “target object” of an entry call or requeue.

3.b

Don't confuse the term “assignment operation” with the assignment_statement. The assignment operation is just one part of the execution of an assignment_statement. The assignment operation is also a part of the execution of various other constructs; see 7.6.1, “Completion and Finalization” for a complete list. Note that when we say, “such-and-such is assigned to so-and-so”, we mean that the assignment operation is being applied, and that so-and-so is the target of the assignment operation.

Name Resolution Rules

4/2

The variable_name of an assignment_statement is expected to be of any type. The expected type for the expression is the type of the target.

4.a

implementation note

An assignment_statement as a whole is a “complete context”, so if the variable_name of an assignment_statement is overloaded, the expression can be used to help disambiguate it. For example:

4.b

type P1 is access R1;
  type P2 is access R2;

4.c
function F return P1;
  function F return P2;

4.d
X : R1;
begin
  F.all := X;  -- Right hand side helps resolve left hand side

Legality Rules

5/2

The target [denoted by the variable_name] shall be a variable of a nonlimited type.

6

If the target is of a tagged class-wide type T'Class, then the expression shall either be dynamically tagged, or of type T and tag-indeterminate (see 3.9.2).

6.a

reason

This is consistent with the general rule that a single dispatching operation shall not have both dynamically tagged and statically tagged operands. Note that for an object initialization (as opposed to the assignment_statement), a statically tagged initialization expression is permitted, since there is no chance for confusion (or Tag_Check failure). Also, in an object initialization, tag-indeterminate expressions of any type covered by T'Class would be allowed, but with an assignment_statement, that might not work if the tag of the target was for a type that didn't have one of the dispatching operations in the tag-indeterminate expression.

Dynamic Semantics

7

For the execution of an assignment_statement, the variable_name and the expression are first evaluated in an arbitrary order.

7.a

ramification

Other rules of the language may require that the bounds of the variable be determined prior to evaluating the expression, but that does not necessarily require evaluation of the variable_name, as pointed out by the ACID.

8

When the type of the target is class-wide:

9

• If the expression is tag-indeterminate (see 3.9.2), then the controlling tag value for the expression is the tag of the target;
  

9.a

ramification

See 3.9.2, “Dispatching Operations of Tagged Types”.

10

• Otherwise [(the expression is dynamically tagged)], a check is made that the tag of the value of the expression is the same as that of the target; if this check fails, Constraint_Error is raised.
  

11/5

The value of the expression is converted to the subtype of the target. [The conversion can raise an exception (see 4.6).]

11.a

ramification

4.6, “Type Conversions” defines what actions and checks are associated with subtype conversion. For non-array subtypes, it is just a constraint check presuming the types match. For array subtypes, it checks the lengths and slides if the target is constrained. “Sliding” means the array doesn't have to have the same bounds, so long as it is the same length.

12/5

In cases involving controlled types, the target is finalized, and an anonymous object can be used as an intermediate in the assignment, as described in 7.6.1, “Completion and Finalization”. In any case, the converted value of the expression is then assigned to the target, which consists of the following two steps:

12.a

To be honest: 7.6.1 actually says that finalization happens always, but unless controlled types are involved, this finalization during an assignment_statement does nothing.

13

• The value of the target becomes the converted value.
  
14/5
• If any part of the target is controlled, its value is adjusted as explained in 7.6.
  

14.a

ramification

If any parts of the object are controlled, abort is deferred during the assignment operation itself, but not during the rest of the execution of an assignment_statement.

15

NOTE The tag of an object never changes; in particular, an assignment_statement does not change the tag of the target.

16/2

This paragraph was deleted.

16.a

ramification

The implicit subtype conversion described above for assignment_statements is performed only for the value of the right-hand side expression as a whole; it is not performed for subcomponents of the value.

16.b

The determination of the type of the variable of an assignment_statement may require consideration of the expression if the variable name can be interpreted as the name of a variable designated by the access value returned by a function call, and similarly, as a component or slice of such a variable (see 8.6, “The Context of Overload Resolution”).

Examples

17

Examples of assignment statements:

18

Value := Max_Value - 1;
Shade := Blue;


Next_Frame(F)(M, N) := 2.5;        -- see 4.1.1
U := Dot_Product(V, W);            -- see 6.3

20/4
Writer := (Status => Open, Unit => Printer, Line_Count => 60);
                                   -- see 3.8.1
Next.all := (72074, null, Head);   -- see 3.10.1

21

Examples involving scalar subtype conversions:

22

I, J : Integer range 1 .. 10 := 5;
K    : Integer range 1 .. 20 := 15;
 ...


I := J;  -- identical ranges
K := J;  -- compatible ranges
J := K;  -- will raise Constraint_Error if K > 10

24

Examples involving array subtype conversions:

25

A : String(1 .. 31);
B : String(3 .. 33);
 ...


A := B;  -- same number of components


A(1 .. 9)  := "tar sauce";
A(4 .. 12) := A(1 .. 9);  -- A(1 .. 12) = "tartar sauce"

28/5

Assignment_statements are well-defined even in the case of overlapping slices of the same array, because the variable_name and expression are both evaluated before copying the value into the variable. In the above example, an implementation yielding A(1 .. 12) = "tartartartar" would be incorrect.

Extensions to Ada 83

29.a

We now allow user-defined finalization and value adjustment actions as part of assignment_statements (see 7.6, “Assignment and Finalization”).

Wording Changes from Ada 83

29.b

The special case of array assignment is subsumed by the concept of a subtype conversion, which is applied for all kinds of types, not just arrays. For arrays it provides “sliding”. For numeric types it provides conversion of a value of a universal type to the specific type of the target. For other types, it generally has no run-time effect, other than a constraint check.

29.c

We now cover in a general way in 3.7.2 the erroneous execution possible due to changing the value of a discriminant when the variable in an assignment_statement is a subcomponent that depends on discriminants.

Incompatibilities With Ada 95

29.d/2

The change of the limited check from a resolution rule to a legality rule is not quite upward compatible. For example

29.e/2

type AccNonLim is access NonLim;
function Foo (Arg : in Integer) return AccNonLim;
type AccLim is access Lim;
function Foo (Arg : in Integer) return AccLim;
Foo(2).all := Foo(1).all;

29.f/2

where NonLim is a nonlimited type and Lim is a limited type. The assignment is legal in Ada 95 (only the first Foo would be considered), and is ambiguous in Ada 2005. We made the change because we want limited types to be as similar to nonlimited types as possible. Limited expressions are now allowed in all other contexts (with a similar incompatibility), and it would be odd if assignments had different resolution rules (which would eliminate ambiguities in some cases). Moreover, examples like this one are rare, as they depend on assigning into overloaded function calls.

5.2.1 Target Name Symbols

1/5

@, known as the target name of an assignment statement, provides an abbreviation to avoid repetition of potentially long names in assignment statements.

Syntax

2/5

target_name ::= @

Name Resolution Rules

3/5

[If a target_name occurs in an assignment_statement A, the variable_name V of A is a complete context. The target name is a constant view of V, having the nominal subtype of V.]

3.a/5

proof

The complete context rule is formally given in 8.6. The constant view rule is formally given in 3.3; the nominal subtype is a property taken from the target object as described below in Dynamic Semantics.

Legality Rules

4/5

A target_name shall appear only in the expression of an assignment_statement.

Dynamic Semantics

5/5

For the execution of an assignment_statement with one or more target_names appearing in its expression, the variable_name V of the assignment_statement is evaluated first to determine the object denoted by V, and then the expression of the assignment_statement is evaluated with the evaluation of each target_name yielding a constant view of the target whose properties are otherwise identical to those of the view provided by V. The remainder of the execution of the assignment_statement is as given in 5.2.

5.a/5

To be honest: The properties here include static properties like whether the target_name is aliased and the nominal subtype of the target_name. It was too weird to give separate rules for static and dynamic properties that said almost the same thing.

5.b/5

ramification

Use of a target_name can be erroneous if the variable_name V is a discriminant-dependent component, and some other constituent of the expression modifies the discriminant governing the component V. The assignment probably would be erroneous anyway, but the use of a target_name eliminates the possibility that a later evaluation of V raises an exception before any erroneous execution occurs. See 3.7.2.

Examples

6/5

Examples of the use of target name symbols:

7/5

Board(1, 1) := @ + 1.0;
            -- An abbreviation for Board(1, 1) := Board(1, 1) + 1.0;
            -- (Board is declared in 3.6.1).

8/5
My_Complex_Array : array (1 .. Max) of Complex; -- See 3.3.2, 3.8.
...
-- Square the element in the Count (see 3.3.1) position:
My_Complex_Array (Count) := (Re => @.Re**2 - @.Im**2,
                             Im => 2.0 * @.Re * @.Im);
   -- A target_name can be used multiple times and
   -- as a prefix if desired.

Extensions to Ada 2012

8.a/5

The target name symbol @ is new.